【Excel2007】countif函数用法汇总
countif 是非常常用的excel函数，本文对其常用的用法进行了汇总，如有缺失和错误欢迎打家指出！
（一）求各种类型单元格个数
真空单元格 =COUNTIF(data1,”=”)
真空+假空单元格 =COUNTIF(data1,”") 相当于countblank()函数
非真空单元格 =COUNTIF(data1,”<>”) 相当于counta()函数
文本型单元格 =COUNTIF(data1,”*”) 假空单元格也是文本型单元格
区域内所有单元格 =COUNTIF(data1,”<>”"”)
数字型单元格 =COUNT(data1) 不是countif()，这里顺便点一下。
（二）求大于或小于等于某个值的单元格个数
>50 =COUNTIF(data2,”>50″)
=50 =COUNTIF(data2,50)
<50 =COUNTIF(data2,”<50″)
>=50 =COUNTIF(data2,”>=50″)
<=50 =COUNTIF(data2,”<=50″)
>E21单元格的值 =COUNTIF(data2,”>”&$E$21)
=E21单元格的值 =COUNTIF(data2,$E$21)
<E21单元格的值 =COUNTIF(data2,”<”&$E$21)
>=E21单元格的值 =COUNTIF(data2,”>=”&$E$21)
<=E21单元格的值 =COUNTIF(data2,”<=”&$E$21)
（三）求等于或包含某N个特定字符的单元格个数
2个字符 =COUNTIF(data3,”??”)
2个字符并且第2个是B =COUNTIF(data3,”?B”)
包含B =COUNTIF(data3,”*B*”)
第2个字符是B =COUNTIF(data3,”?B*”)
等于“你好” =COUNTIF(data3,”你好”)
包含D38单元格的内容 =COUNTIF(data3,”*”&D38&”*”)
第2字是D38单元格的内容 =COUNTIF(data3,”?”&D38&”*”)
备注：countif()函数对英文字母不区分大小写
（四）不连续区域求个数
三个区域中>=60 =SUM( COUNTIF ( INDIRECT( {“a1:a10″,”b2:b20″,”c3:c30″} ), “>=60″))
三个区域中 =70 =SUM( COUNTIF ( INDIRECT( {“a1:a10″,”b2:b20″,”c3:c30″} ), 70))
三个区域中 <60 =SUM( COUNTIF ( INDIRECT( {“a1:a10″,”b2:b20″,”c3:c30″} ), “<60″))
（五）两个条件求个数
>10并且<=15 =SUM(COUNTIF(data4,”>”&{10,15})*{1,-1})
>=10并且<15 =SUM(COUNTIF(data4,”>=”&{10,15})*{1,-1})
>=10并且<=15 =SUM(COUNTIF(data4,{“>=10″,”>15″})*{1,-1})
>10并且<15 =SUM(COUNTIF(data4,{“>10″,”>=15″})*{1,-1})
>10并且<=15 =COUNTIF(data4,”>10″)-COUNTIF(data4,”>15″)
（六）检验数据是否重复以及重复次数的验证
这个比较简单，数据区域中对每个单元格数据使用countif 可判断其在区域内重复与否以及重复次数，
（七）避免录入重复数据
在excel工作表菜单栏，用鼠标点击数据→有效性→设置有效性条件，在允许下拉按纽中选择自定义，在公式框中输入 =COUNTIF(data5,A1)<2。这样即实现了数据data5区域中不重复的验证条件。
（四）中，两边的都是以60为基准，为什么中间的换70了？
故意的？
为了与文章第一句想对应嚒？O(∩_∩)O~
（四）中，两边都是以60为基准的，为什么中间要换成70了？
故意的？
还是为了与文章开头第一句相对应哈。
师傅，需求来啦
有机会介绍下 sumproduct 函数哈
（五）中的 “>10并且{10,15})*{1,-1})”这个来实现
嘿嘿
最近较忙，总结好了发上来